Family Forum 260/SOMC Family Forum 260 - Disc 2.iso/Somc.dir/00001_Script_Start Movie

Text File | 1999-01-19 | 5KB | 176 lines

on startMovie


   --* open or create  file

  set STARTM to new(xtra "fileio")
  createFile STARTM, "c:\STARTM.SMC"


  --* set whichsneak to the sneakpeak to be used (EDU,FAMILY,GAME,KIDS,MAC,PROD)

  Global WHICHSNEAK
  set WHICHSNEAK to "GAME"


  --* set the paths and exe for the setups

  global P1SETUP,P2SETUP,P3SETUP,P4SETUP,M1SETUP,M2SETUP,M3SETUP,M4SETUP
  set P1SETUP to "@\INSTALL\SETUP.EXE" --FINANCE
  set P2SETUP to "@\SETUP.EXE" --CRASPER
  set P3SETUP to "@\PHOTOSHP\SETUP.EXE"--PHOTOSHP
  set P4SETUP to "@\HB6DEMO\setuphb.EXE"--HARDBALL
  --* MANUAL HELPS FOR PROGRAMS
  set M1SETUP to "@\SOMC\MANUALS\HLPreadme1.EXE" --FINANCE
  set M2SETUP to "@\SOMC\MANUALS\readme1.EXE" --CRASPER
  set M3SETUP to "@\SOMC\MANUALS\WRIREADME1.EXE"--PHOTOSHP
  set M4SETUP to "@\SOMC\MANUALS\README3.EXE"--HARDBALL



  --  --* CHANGE HEADER
  --
  --  case WHICHSNEAK of
  --    "EDU"   :set the memberNum of sprite 3 to the memberNum of member "EDU HEADER"
  --    "FAMILY":set the memberNum of sprite 3 to the memberNum of member "FAM HEADER"
  --    "GAME"  :set the memberNum of sprite 3 to the memberNum of member "GAME HEADER"
  --    "KIDS"  :set the memberNum of sprite 3 to the memberNum of member "KIDS HEADER"
  --    "MAC"   :set the memberNum of sprite 3 to the memberNum of member "MAC HEADER"
  --    "PROD"  :set the memberNum of sprite 3 to the memberNum of member "PROD HEADER"
  --
  --  end case





  --* This declares the variables for the finger cursor. *

  global mFINGER, mFINGERMASK
  set mFINGER to the number of member "Finger1"
  set mFINGERMASK to the number of member "Finger2"
  glowClear()

end





--* This handler hides/shows the glow images. eg: glow(5,TRUE) *

on glow WHICHSPRITE, TRUEORFALSE
  set the visible of sprite WHICHSPRITE to TRUEORFALSE
end glow

--* TURN OF ALL GLOWS ON START
on glowClear
  repeat with i = 20 to 39
    glow(i)
  end repeat
end

--* This handler switches the text color for a glow effect. eg.textglow("Hello",1)*

on textglow WHICHMEMBER, COLORNUMBER
  set the foreColor of member WHICHMEMBER to COLORNUMBER
end textglow


--* THIS HANDLER OPEN AND CENTERS A MOVIE IN A WINDOW *

on openMIAW MYWINDOW
  set myRect=the rect of window MYWINDOW
  set myStage=the rect of the Stage
  set myWidth=(getAt(myRect,3)-getAt(myRect,1))
  set myHeight=(getAt(myRect,4)-getAt(myRect,2))
  set myLocH=((getAt(myStage,3)+getAt(myStage,1))/2)-(myWidth/2)
  set myLocV=((getAt(myStage,2)+getAt(myStage,4))/2)-(myHeight/2)
  set myNewRect=rect(myLocH,myLocV,(myLocH+myWidth),(myLocV+myHeight))
  set the rect of window MYWINDOW=myNewRect
  set the windowType of window MYWINDOW to 2
  open window MYWINDOW
end openMIAW


--* THIS HANDLER TURNS THE SPRITE PASSED TO IT TO INVISIBLE AND RESETS THE CURSOR
on doRollout numsprite
  glow(numsprite,FALSE)
  cursor 0
end

--* PLAYS A CLICK SOUND

on doClick
  puppetsound 1,"clicksound"
  updateStage
end

--* CHECK THE ANSWER FOR WORDWIZE

on  checkAnswer

  global CORRECT,Ncount,ANSWER,TRIES,RIGHT

  put line Ncount of the text of member "ww3" into member "definition"
  set the fontSize of member "definition" to 18
  set the fontstyle of member "definition" to "bold"
  glow(20,TRUE)
  set TRIES to TRIES + 1
  if answer = CORRECT then
    glow(52,TRUE)
    puppetsound 1,"Woww1"
    updateStage
    set RIGHT to RIGHT + 1
  else
    glow(53,TRUE)
    puppetsound 1,"Buzzer2"
    updateStage
  end if
end

on finish

  global TRIES,RIGHT,scoreSTR

  go to "FIN"
  if (TRIES) THEN
    if ((float(RIGHT) / float(TRIES)) > .49) then
      puppetsound 1,"Glfclap1"
      updateStage
    end if
  end if
  set scoreSTR2 to "YOU GOT"&&string(RIGHT)&&"OUT OF"&&string(TRIES)&&"RIGHT"
  set the text of member "scoreSTR" to scoreSTR2
  updateStage

end

-- Delays for x number of seconds
on timedelay SECONDS
  startTimer
  repeat while the timer < SECONDS * 60
    nothing
  end repeat
end


on doRollover numsprite,SOUNDNUM

  global mfinger,mfingermask

  cursor[mfinger,mfingermask]
  glow(numsprite,TRUE)
  updatestage
  case SOUNDNUM of
    1:
      puppetsound 1, "rollsound"
      --  repeat while soundbusy(1)
      --  end repeat
    2:
      puppetsound 1, "rollsound2"
      --  repeat while soundbusy(1)
      --  end repeat
  end case
end